package controls
{
    /** Try to load an image directly, if that fails, proxy it through our server
     */
   
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.ProgressEvent;
    import flash.events.SecurityErrorEvent;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.system.LoaderContext;
   
    import mx.controls.Image;
    import mx.core.mx_internal;

    use namespace mx_internal;

    public class ProxyImage extends Image
    {
        private var _fDoneChecking:Boolean = false;
       
        public function ProxyImage()
        {
            super();
            loaderContext = new LoaderContext(true);
           
            // TEST: This is test code to see if it worked
            addEventListener(Event.COMPLETE, OnComplete);
        }
       
        private var _urll:URLLoader = null;
       
        private function SetSource(str:String): void {
            super.source = str;
        }
       
        private function CreateProxyUrl(strUrl:String): String {
            // Do some magic
            strUrl = "/get?url=" + encodeURIComponent(strUrl);
            return strUrl;
        }
       
        override public function set source(value:Object):void {
            if (_urll) {
                try {
                    _urll.close();
                } catch (e:Error) {
                   
                }
                _urll = null;
            }
           
            // UNDONE: Check for known sites, e.g. Picnik, Flickr, Picasa
            if (value is String) {
                var fnOnSuccess:Function = function(evt:Event): void {
                    // Found a cross domain. Just load it directly
                    SetSource(String(value));
                    try {
                        _urll.close();                     
                    } catch (e:Error) {
                        // ignore
                    }
                    _urll = null;
                }
               
                var fnOnError:Function = function(evt:Event): void {
                    // Found a cross domain. Just load it directly
                    SetSource(CreateProxyUrl(String(value)));
                    try {
                        _urll.close();                     
                    } catch (e:Error) {
                        // ignore
                    }
                    _urll = null;
                }
               
                var urll:URLLoader = new URLLoader();
                _urll = urll;
                urll.addEventListener(Event.COMPLETE, fnOnSuccess);
                urll.addEventListener(IOErrorEvent.IO_ERROR, fnOnSuccess);
                urll.addEventListener(Event.OPEN, fnOnSuccess);
                urll.addEventListener(ProgressEvent.PROGRESS, fnOnSuccess);
                urll.addEventListener(SecurityErrorEvent.SECURITY_ERROR, fnOnError);
                urll.load(new URLRequest(String(value)));
            } else {
                // Not a string, no need to proxy
                super.source = value;
            }
            //Security.loadPolicyFile("http://www.supercars.dk/crossdomain.xml");
        }

        // TEst code to make sure our proxy worked.    
        private function OnComplete(evt:Event): void {
            var bmd:BitmapData = (content as Bitmap).bitmapData;
        }
    }
}